Difference between revisions of "Zsh"

Latest revision as of 23:19, 20 June 2017

Zsh is a powerful shell that operates as both an interactive shell and as a scripting language interpreter. While being compatible with Bash (not by default, only if issuing emulate sh), it offers advantages such as improved tab completion and globbing.

The Zsh FAQ offers more reasons to use Zsh.

Installation

Before starting users may want to see what shell is currently being used:

$ echo $SHELL

Install the zsh package. For additional completion definitions, install the zsh-completions package as well.

Initial configuration

Make sure that Zsh has been installed correctly by running the following in a terminal:

$ zsh

You should now see zsh-newuser-install, which will walk you through some basic configuration. If you want to skip this, press q. If you did not see it, you can invoke it manually with

$ zsh /usr/share/zsh/functions/Newuser/zsh-newuser-install -f

Making Zsh your default shell

See Command-line shell#Changing your default shell.

Startup/Shutdown files

When starting Zsh, it will source the following files in this order by default:

• /etc/zsh/zshenv Used for setting system-wide environment variables; it should not contain commands that produce output or assume the shell is attached to a tty. This file will always be sourced, this cannot be overridden.
• $ZDOTDIR/.zshenv Used for setting user's environment variables; it should not contain commands that produce output or assume the shell is attached to a tty. This file will always be sourced.
• /etc/zsh/zprofile Used for executing commands at start, will be sourced when starting as a login shell. Please note that on Arch Linux, by default it contains one line which source the /etc/profile.
  • /etc/profile This file should be sourced by all Bourne-compatible shells upon login: it sets up $PATH and other environment variables and application-specific (/etc/profile.d/*.sh) settings upon login.
• $ZDOTDIR/.zprofile Used for executing user's commands at start, will be sourced when starting as a login shell.
• /etc/zsh/zshrc Used for setting interactive shell configuration and executing commands, will be sourced when starting as an interactive shell.
• $ZDOTDIR/.zshrc Used for setting user's interactive shell configuration and executing commands, will be sourced when starting as an interactive shell.
• /etc/zsh/zlogin Used for executing commands at ending of initial progress, will be sourced when starting as a login shell.
• $ZDOTDIR/.zlogin Used for executing user's commands at ending of initial progress, will be sourced when starting as a login shell.
• $ZDOTDIR/.zlogout Will be sourced when a login shell exits.
• /etc/zsh/zlogout Will be sourced when a login shell exits.

Configure Zsh

Although Zsh is usable out of the box, it is almost certainly not set up the way most users would like to use it, but due to the sheer amount of customization available in Zsh, configuring Zsh can be a daunting and time-consuming experience.

Simple .zshrc

Included below is a sample configuration file, it provides a decent set of default options as well as giving examples of many ways that Zsh can be customized. In order to use this configuration save it as a file named .zshrc.

Here is a simple .zshrc:

~/.zshrc

autoload -Uz compinit promptinit
compinit
promptinit

# This will set the default prompt to the walters theme
prompt walters

Configuring $PATH

Normally, the path should be set in ~/.zshenv, but Arch Linux sources /etc/profile after sourcing ~/.zshenv.

To prevent your $PATH being overwritten, set it in ~/.zprofile.

~/.zprofile

typeset -U path
path=(~/bin /other/things/in/path $path[@])

See also A User's Guide to the Z-Shell and the note in #Startup/Shutdown files.

Command completion

Perhaps the most compelling feature of Zsh is its advanced autocompletion abilities. At the very least, enable autocompletion in .zshrc. To enable autocompletion, add the following to your ~/.zshrc:

~/.zshrc

autoload -Uz compinit
compinit

The above configuration includes ssh/scp/sftp hostnames completion but in order for this feature to work, users need to prevent ssh from hashing hosts names in ~/.ssh/known_hosts.

/etc/ssh/ssh_config

#HashKnownHosts yes

For autocompletion with an arrow-key driven interface, add the following to:

~/.zshrc

zstyle ':completion:*' menu select

To activate the menu, press tab twice.

For autocompletion of command line switches for aliases, add the following to:

~/.zshrc

setopt COMPLETE_ALIASES

Key bindings

Zsh does not use readline, instead it uses its own and more powerful Zsh Line Editor, ZLE. It does not read /etc/inputrc or ~/.inputrc. ZLE has an emacs mode and a vi mode. If one of the $VISUAL or $EDITOR environment variables contain the string vi then vi mode will be used; otherwise, it will default to emacs mode. Set the mode explicitly with bindkey -e or bindkey -v respectively for emacs mode or vi mode.

See ZshWiki: zle:bindkeys for instructions on keybinding setup.

History search

You need to set up #Key bindings to use this. To enable history search add these lines to .zshrc file:

~/.zshrc

autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search

[[ -n "$key[Up]"   ]] && bindkey -- "$key[Up]"   up-line-or-beginning-search
[[ -n "$key[Down]" ]] && bindkey -- "$key[Down]" down-line-or-beginning-search

By doing this, only the past commands matching the current line up to the current cursor position will be shown when Up or Down keys are pressed.

Prompts

Prompt themes

There is a quick and easy way to set up a colored prompt in Zsh. Make sure that prompt theme system is set to autoload in .zshrc. This can be done by adding these lines to:

~/.zshrc

autoload -Uz promptinit
promptinit

Available prompt themes are listed by running the command:

$ prompt -l

For example, to use the walters theme, enter:

$ prompt walters

To preview all available themes, use this command:

$ prompt -p

Customized prompt

For users who are dissatisfied with the prompts mentioned above (or want to expand their usefulness), Zsh offers the possibility to build a custom prompt. Zsh supports a left- and right-sided prompt additional to the single, left-sided prompt that is common to all shells. Customize it by using PROMPT= with prompt escapes.

See Prompt Expansion for a list of prompt variables and conditional substrings, or take a look at the zshmisc(1) manpage.

Colors

Zsh sets colors differently than Bash.

See Visual effects in zshmisc(1) for prompt escapes to set foreground color, background color and other visual effects.

Colors can be specified by numeric color code or by name (see zshzle(1) section CHARACTER HIGHLIGHTING). Most terminals support the following colors by name:

$ print -P '%B%F{red}co%F{green}lo%F{blue}rs%f%b'

Example

This is an example of a two-sided prompt:

PROMPT='%F{red}%n%f@%F{blue}%m%f %F{yellow}%1~%f %# '
RPROMPT='[%F{yellow}%?%f]'

And here's how it will be displayed:

username@host ~ %                                                         [0]

Sample .zshrc files

• A package in offical repository named grml-zsh-config comes from https://grml.org/zsh and provides a zshrc file that includes many tweaks for Zshell. This is the default configuration for the monthly ISO releases.
• https://github.com/MrElendig/dotfiles-alice/blob/master/.zshrc - basic setup, with dynamic prompt and window title/hardinfo.
• https://github.com/slashbeast/things/blob/master/configs/DOTzshrc - zshrc with multiple features, be sure to check out comments into it. Notable features: confirm function to ensure that user want to run poweroff, reboot or hibernate, support for GIT in prompt (done without vcsinfo), tab completion with menu, printing current executed command into window's title bar and more.

See dotfiles#Repositories for more.

Configuration Frameworks

• Antigen — A plugin manager for zsh, inspired by oh-my-zsh and vundle.

https://github.com/zsh-users/antigen || antigen-git^AUR

• oh-my-zsh — A popular, community-driven framework for managing your Zsh configuration. It comes bundled with a ton of helpful functions, helpers, plugins, themes.

https://github.com/robbyrussell/oh-my-zsh || oh-my-zsh-git^AUR

Note: For themes to work you may need to set setopt NO_GLOBAL_RCS in the ~/.zshenv file, otherwise changes to some variables (such as $PROMPT) may be overwritten.

• Prezto — A configuration framework for Zsh. It comes with modules, enriching the command line interface environment with sane defaults, aliases, functions, auto completion, and prompt themes.

https://github.com/sorin-ionescu/prezto || prezto-git^AUR

Tips and tricks

Autostart X at login

See Xinitrc#Autostart X at login.

The "command not found" hook

pkgfile includes a "command not found" hook that will automatically search the official repositories, when entering an unrecognized command.

You need to source the hook to enable it, for example:

~/.zshrc

source /usr/share/doc/pkgfile/command-not-found.zsh

The ttyctl command

[3] describes the ttyctl command in Zsh. This may be used to "freeze/unfreeze" the terminal. Many programs change the terminal state, and often do not restore terminal settings on exiting abnormally. To avoid the need to manually reset the terminal, use the following:

~/.zshrc

ttyctl -f

Remembering recent directories

Dirstack

Zsh can be configured to remember the DIRSTACKSIZE last visited folders. This can then be used to cd them very quickly. You need to add some lines to your configuration file:

.zshrc

DIRSTACKFILE="$HOME/.cache/zsh/dirs"
if [[ -f $DIRSTACKFILE ]] && [[ $#dirstack -eq 0 ]]; then
  dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
  [[ -d $dirstack[1] ]] && cd $dirstack[1]
fi
chpwd() {
  print -l $PWD ${(u)dirstack} >$DIRSTACKFILE
}

DIRSTACKSIZE=20

setopt AUTO_PUSHD PUSHD_SILENT PUSHD_TO_HOME

## Remove duplicate entries
setopt PUSHD_IGNORE_DUPS

## This reverts the +/- operators.
setopt PUSHD_MINUS

Now use

$ dirs -v

to print the dirstack. Use cd -<NUM> to go back to a visited folder. Use autocompletion after the dash. This proves very handy if using the autocompletion menu.

cdr

cdr allows you to change the working directory to a previous working directory from a list maintained automatically. It stores all entries in files that are maintained across sessions and (by default) between terminal emulators in the current session.

See Remembering Recent Directories in zshcontrib(1).

Help command

Zsh help command is called run-help. Unlike bash, zsh does not enable it by default. To use help in zsh, add following to your zshrc:

autoload -Uz run-help
unalias run-help
alias help=run-help

run-help will invoke man for external commands. Default keyboard shortcut is Alt+h or Esc+h.

run-help has helper functions, they need to be enabled separately:

autoload -Uz run-help-git
autoload -Uz run-help-ip
autoload -Uz run-help-openssl
autoload -Uz run-help-p4
autoload -Uz run-help-sudo
autoload -Uz run-help-svk
autoload -Uz run-help-svn

For example run-help git commit command will now open the man page git-commit(1) instead of git(1).

Fish-like syntax highlighting

Fish provides a very powerful shell syntax highlighting. To use this in zsh, you can install zsh-syntax-highlighting from offical repository and add following to your zshrc:

source /usr/share/zsh/plugins/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh

Persistent rehash

Typically, compinit will not automatically find new executables in the $PATH. For example, after you install a new package, the files in /usr/bin would not be immediately or automatically included in the completion. Thus, to have these new exectuables included, one would run:

$ rehash

This 'rehash' can be set to happen automatically. Simply include the following in your zshrc:

~/.zshrc

zstyle ':completion:*' rehash true

Bind key to ncurses application

Bind a ncurses application to a keystoke, but it will not accept interaction. Use BUFFER variable to make it work. The following example lets users open ncmpcpp using Alt+\:

~/.zshrc

ncmpcppShow() { BUFFER="ncmpcpp"; zle accept-line; }
zle -N ncmpcppShow
bindkey '^[\' ncmpcppShow

An alternate method, that will keep everything you entered in the line before calling application:

~/.zshrc

ncmpcppShow() { ncmpcpp <$TTY; zle redisplay; }
zle -N ncmpcppShow
bindkey '^[\' ncmpcppShow

File manager key binds

Key binds like those used in graphic file managers may come handy. The first comes back in directory history (Alt+Left), the second let the user go to the parent directory (Alt+Up). They also display the directory content.

~/.zshrc

cdUndoKey() {
  popd
  zle       reset-prompt
  echo
  ls
  zle       reset-prompt
}

cdParentKey() {
  pushd ..
  zle      reset-prompt
  echo
  ls
  zle       reset-prompt
}

zle -N                 cdParentKey
zle -N                 cdUndoKey
bindkey '^[[1;3A'      cdParentKey
bindkey '^[[1;3D'      cdUndoKey

xterm title

xterm title is set with xterm escape sequences. For example:

print -n '\e]2;My xterm title\a'

will set the title to

My xterm title

An simple way to have a dynamic title is to set the title in a hook function, particularly precmd and preexec.

By using print -P you can take advantage of prompt escapes. Title printing can be split up in multiple commands as long as they are sequential.

~/.zshrc

autoload -Uz add-zsh-hook

function xterm_title_precmd () {
	print -Pn '\e]2;%n@%m %1~\a'
}

function xterm_title_preexec () {
	print -Pn '\e]2;%n@%m %1~ %# '
	print -n "${(q)1}\a"
}

if [[ "$TERM" == (screen*|xterm*|rxvt*) ]]; then
	add-zsh-hook -Uz precmd xterm_title_precmd
	add-zsh-hook -Uz preexec xterm_title_preexec
fi

Uninstallation

Change the default shell before removing the zsh package.

Run following command:

$ chsh -s /bin/bash user

Use it for every user with zsh set as their login shell (including root if needed). When completed, the zsh package can be removed.

Alternatively, change the default shell back to Bash by editing /etc/passwd as root.

For example, change the following:

username:x:1000:1000:Full Name,,,:/home/username:/bin/zsh

To this:

username:x:1000:1000:Full Name,,,:/home/username:/bin/bash

See also

• A User's Guide to ZSH
• The Z Shell Manual (different format available here)
• Zsh FAQ
• zsh-lovers(1) (available as zsh-lovers package)
• Zsh Wiki
• Gentoo: Zsh/Guide
• Bash2Zsh Reference Card